क्या किसी दिए गए एक्सेल स्प्रेडशीट में सभी सरणी सूत्रों को खोजने का कोई तरीका है?

9
NeedHelp 9 मई 2011, 19:18

2 जवाब

सबसे बढ़िया उत्तर

इस उदाहरण पर एक नज़र डालें। आशा है कि यह मदद करता है।

Sub array_formula()
Dim rRange As Range, cell As Range
Dim tot As Integer
Set rRange = ActiveSheet.UsedRange.SpecialCells(xlCellTypeFormulas)
    For Each cell In rRange
        If cell.HasArray Then
            MsgBox cell.Address & " " & cell.formula
            tot = tot + 1
         End If
     Next cell
MsgBox "total number of array formula: " & tot
End Sub
11
Nicola Cossu 9 मई 2011, 20:26

मौजूदा पर थोड़ा अपग्रेड (जो मुझे काफी उपयोगी लगा धन्यवाद) जो सभी शीट्स को खोजेगा।

Sub debug_print_array_formulas_all_sheets()
    Dim ws As Worksheet
    Dim rRange As Range, cell As Range
    Dim tot As Integer

    For Each ws In ThisWorkbook.Sheets
        On Error GoTo NotFound
        ws.Unprotect
        Dim v As Variant
        v = ws.UsedRange.HasFormula
        If IsNull(v) Or v Then

            Set rRange = ws.UsedRange.SpecialCells(xlCellTypeFormulas)
            tot = 0
            For Each cell In rRange
                If cell.HasArray Then
                    Debug.Print ws.Name & ":" & cell.Address & " " & cell.Formula
                    tot = tot + 1
                End If
             Next cell
             If tot > 0 Then
                Debug.Print "total number of array formula on " & ws.Name & ": " & tot
                tot = 0
             End If 
    NotFound:
        End If
    Next ws
End Sub
3
Scott Gall 17 अक्टूबर 2018, 21:54