ऐसन का उपयोग करके नेस्टेड सूची के साथ पार्सिंग सूची

यदि आप पहले से ही उस प्रकार के बारे में जानते हैं जो इरादा के अनुसार पार्स करता है तो शायद सबसे आसान समाधान उस प्रकार के संदर्भ में अपना उदाहरण लिखना और अनुवाद करना है:

import Data.Aeson
import GHC.Generics
import qualified Data.ByteString.Lazy as L

data Ch = Ch {
   c1 :: String,
   c2 :: (String, String)
} deriving (Show, Generic)

instance FromJSON Ch where
    parseJSON x =
        do (a,(b,c)) <- parseJSON x
           pure (Ch a (b,c))

और परिणाम है:

*Main> :set -XOverloadedStrings
*Main> eitherDecode "[\"a\", [\"b\", \"c\"]]" :: Either String Ch
Right (Ch {c1 = "a", c2 = ("b","c")})

संपादित करें:

ईसन के एपीआई का अधिक प्रत्यक्ष उपयोग सूचनात्मक या पसंदीदा हो सकता है:

instance FromJSON Ch where
    parseJSON =
       withArray "Ch" $ \arr ->
       -- from Data.Aeson.Types
           if V.length arr /= 2
              -- ^ from Data.Vector
              then typeMismatch "Length should be 2" (Array arr)
                   -- ^ from Data.Aeson.Types
              else Ch <$> parseJSON (arr ! 0) <*> parseJSON ( arr ! 1 )