मैं एलन ब्राउन के ConcatRelated() फ़ंक्शन का उपयोग कर रहा हूं, लेकिन बड़े डेटा सेट के साथ यह महसूस कर रहा हूं कि डेटा अधूरा है।

क्या इस फ़ंक्शन की कोई वर्ण सीमा है, और यदि ऐसा है - क्या कोई भिन्न फ़ंक्शन /UDF है जो समान परिणाम प्राप्त कर सकता है?

यह फ़ंक्शन है: - और मूल थ्रेड से वापस लिंक करें http://allenbrowne.com/func-concat. एचटीएमएल

Public Function ConcatRelated(strField As String, _
    strTable As String, _
    Optional strWhere As String, _
    Optional strOrderBy As String, _
    Optional strSeparator = ", ") As Variant
On Error GoTo Err_Handler
    'Purpose:   Generate a concatenated string of related records.
    'Return:    String variant, or Null if no matches.
    'Arguments: strField = name of field to get results from and concatenate.
    '           strTable = name of a table or query.
    '           strWhere = WHERE clause to choose the right values.
    '           strOrderBy = ORDER BY clause, for sorting the values.
    '           strSeparator = characters to use between the concatenated values.
    'Notes:     1. Use square brackets around field/table names with spaces or odd characters.
    '           2. strField can be a Multi-valued field (A2007 and later), but strOrderBy cannot.
    '           3. Nulls are omitted, zero-length strings (ZLSs) are returned as ZLSs.
    '           4. Returning more than 255 characters to a recordset triggers this Access bug:
    '               http://allenbrowne.com/bug-16.html
    Dim rs As DAO.Recordset         'Related records
    Dim rsMV As DAO.Recordset       'Multi-valued field recordset
    Dim strSql As String            'SQL statement
    Dim strOut As String            'Output string to concatenate to.
    Dim lngLen As Long              'Length of string.
    Dim bIsMultiValue As Boolean    'Flag if strField is a multi-valued field.

    'Initialize to Null
    ConcatRelated = Null

    'Build SQL string, and get the records.
    strSql = "SELECT " & strField & " FROM " & strTable
    If strWhere <> vbNullString Then
        strSql = strSql & " WHERE " & strWhere
    End If
    If strOrderBy <> vbNullString Then
        strSql = strSql & " ORDER BY " & strOrderBy
    End If
    Set rs = DBEngine(0)(0).OpenRecordset(strSql, dbOpenDynaset)
    'Determine if the requested field is multi-valued (Type is above 100.)
    bIsMultiValue = (rs(0).Type > 100)

    'Loop through the matching records
    Do While Not rs.EOF
        If bIsMultiValue Then
            'For multi-valued field, loop through the values
            Set rsMV = rs(0).Value
            Do While Not rsMV.EOF
                If Not IsNull(rsMV(0)) Then
                    strOut = strOut & rsMV(0) & strSeparator
                End If
                rsMV.MoveNext
            Loop
            Set rsMV = Nothing
        ElseIf Not IsNull(rs(0)) Then
            strOut = strOut & rs(0) & strSeparator
        End If
        rs.MoveNext
    Loop
    rs.Close

    'Return the string without the trailing separator.
    lngLen = Len(strOut) - Len(strSeparator)
    If lngLen > 0 Then
        ConcatRelated = Left(strOut, lngLen)
    End If

Exit_Handler:
    'Clean up
    Set rsMV = Nothing
    Set rs = Nothing
    Exit Function

Err_Handler:
    MsgBox "Error " & Err.Number & ": " & Err.Description, vbExclamation, "ConcatRelated()"
    Resume Exit_Handler
End Function

संपादित करें
मैं वीबीए का उपयोग कर रहा हूं और एक Into स्टेटमेंट चला रहा हूं। क्या यह बेहतर काम करेगा यदि मैंने पहले तालिका तैयार की और फिर डेटा डाला?

वर्तमान संरचना

DoCmd.RunSQL "Select DISTINCT [ImportTable].DSFNum, 

ConcatRelated('[Item]','[ImportTable]','[DSFNum] =' & [DSFNum]) AS Item, 
ConcatRelated('[Count]','[ImportTable]','[DSFNum] =' & [DSFNum]) AS Count 
INTO [OneRowTable] 
FROM [ImportTable]"
0
Smith Stanley 31 अक्टूबर 2017, 16:03

1 उत्तर

सबसे बढ़िया उत्तर

सभी प्रासंगिक जानकारी ConcatRelated फ़ंक्शन के कोड में पाई जा सकती है:

  1. नोट्स: किसी रिकॉर्डसेट में 255 से अधिक वर्णों को वापस करने से यह एक्सेस बग ट्रिगर होता है: http://allenbrowne.com/bug-16.html

जैसा कि उस पृष्ठ पर पाया जा सकता है, समस्या फ़ंक्शन नहीं है, लेकिन तथ्य यह है कि एक्सेस में एक टेक्स्ट फ़ील्ड में कई वर्ण नहीं हो सकते हैं, और कुछ का उपयोग करके इसे ठीक किया जा सकता है

SELECT ID, MuchText FROM StructureOnly 
UNION ALL
SELECT ID, ConcatRelated(something, table, where) AS MuchText FROM LotsaText;

जहां MuchText एक मेमो फील्ड है

वीबीए और रिकॉर्डसेट का उपयोग कर वर्कअराउंड:

Dim rsSelect As DAO.Recordset
Dim rsInsert As DAO.Recordset
Dim db As DAO.Database
Set db = CurrentDb
Set rsSelect = db.OpenRecordset ("Select DISTINCT [ImportTable].DSFNum FROM [ImportTable]")
Set rsInsert = db.OpenRecordset("OneRowTable")
Do While Not rsSelect.EOF
    rsInsert.AddNew
    rsInsert!DSFNum = rsSelect!DSFNum
    rsInsert!Item = ConcatRelated("[Item]","[ImportTable]","[DSFNum] =" & rsSelect!DSFNum)
    rsInsert!Count = ConcatRelated("[Count]","[ImportTable]","[DSFNum] =" & rsSelect!DSFNum)
    rsInsert.Update
    rsSelect.MoveNext
Loop
2
Erik A 31 अक्टूबर 2017, 17:04