मैं गलती से अपना ईमेल खाता और उस खाते के सभी ईमेल हटा देता हूं। क्या ईमेल को पुनर्प्राप्त करने का कोई मौका है? मैं इसे कैसे पुनर्प्राप्त कर सकता हूं? धन्यवाद।

0
Gene9y 26 मार्च 2020, 05:47

1 उत्तर

सबसे बढ़िया उत्तर

चार महीने पहले मैं आउटलुक स्टोर्स का स्थान बताते हुए ओम3आर की टिप्पणी से सहमत होता। लेकिन मैंने दिसंबर में एक नया लैपटॉप खरीदा और अब आउटलुक फाइलें वह नहीं हैं जहां सभी दस्तावेज कहते हैं कि उन्हें होना चाहिए। इससे भी बदतर, मैं फाइल एक्सप्लोरर का उपयोग करके आउटलुक फाइलों वाले फ़ोल्डरों तक नहीं पहुंच सकता, हालांकि मैं उन्हें वीबीए के साथ ढूंढ सकता हूं।

नीचे दिया गया मैक्रो OST या PST के एक्सटेंशन वाली फ़ाइलों के लिए ड्राइव C को खोजता है। मैं यह वादा नहीं कर सकता कि यह मैक्रो आपके खोए हुए स्टोर को ढूंढ लेगा, लेकिन अगर यह अभी भी आपकी डिस्क पर है, तो यह इसे ढूंढ लेगा। यदि आपको लापता स्टोर मिल जाता है, तो संभवतः आपको इसे कहीं पहुंच योग्य स्थान पर ले जाने के लिए वीबीए का उपयोग करना होगा।

नीचे दिए गए मैक्रो को मैक्रो-सक्षम कार्यपुस्तिका में कॉपी करें और इसे चलाएं। जबकि यह सक्रिय कार्यपत्रक चल रहा है, ऐसा दिखेगा:

1923 Folders to search
 327 Folders searched           

     Store       Size      Date Folder
     $ILJARJ0.pst   212   28Mar20 C:\$Recycle.Bin\S-1-5-21-3957073674-21115239-22921093-1001
     $IMS96DJ.pst   212   28Mar20 C:\$Recycle.Bin\S-1-5-21-3957073674-21115239-22921093-1001

शीर्ष दो पंक्तियाँ एक अपरिष्कृत प्रगति संकेतक देती हैं। मेरे लैपटॉप पर, 69190 फ़ोल्डरों की खोज के साथ दिनचर्या समाप्त होती है। मुझे नहीं पता कि मेरे रीसायकल बिन में पीएसटी फाइलें क्यों हैं। मैंने 28 मार्च को कुछ भी प्रासंगिक नहीं किया। जब दिनचर्या समाप्त हो जाती है, तो मैक्रो को मिलने वाले प्रत्येक स्टोर की एक ऑटो-फिटेड सूची होगी। मेरे लैपटॉप पर कोई भी ऐसा नहीं है जहां मैं उम्मीद करता हूं और कुछ डुप्लीकेट हैं। मुझे आशा है कि आपको अपना स्टोर मिल जाएगा।

Option Explicit
Sub SearchForStoresOnC()

  ' Searches drive C for files with an extension of PST or OST
  ' Warning: overwrites the active workbook

  Dim ErrNum As Long
  Dim FileAttr As Long
  Dim FileName As String
  Dim FldrName As String
  Dim RowCrnt As Long
  Dim ToSearch As Collection

  Cells.EntireRow.Delete
  Range("A1").Value = 0
  Range("A2").Value = 0
  Range("B1").Value = "Folders to search"
  Range("B2").Value = "Folders searched"
  Range("B4").Value = "Store"
  With Range("C4")
    .Value = "Size"
    .HorizontalAlignment = xlRight
  End With
  With Range("D4")
    .Value = "Date"
    .HorizontalAlignment = xlRight
  End With
  Range("E4") = "Folder"
  RowCrnt = 5

  Set ToSearch = New Collection
  ' Load ToSearch with drive to search.
  ToSearch.Add "C:"

  Do While ToSearch.Count > 0

    FldrName = ToSearch(1)
    ToSearch.Remove 1

    Err.Clear
    ErrNum = 0
    On Error Resume Next
    ' Stores are unlikely to be hidden but can be in folders that are hidden
    FileName = Dir$(FldrName & "\*.*", vbDirectory + vbHidden + vbSystem)
    ErrNum = Err.Number
    On Error GoTo 0
    If ErrNum <> 0 Then
      'Debug.Print "Dir error: " & FldrName
    Else
      Do While FileName <> ""
        If FileName = "." Or FileName = ".." Then
          ' Ignore pointers
        Else
          Err.Clear
          On Error Resume Next
          FileAttr = GetAttr(FldrName & "\" & FileName)
          ErrNum = Err.Number
          On Error GoTo 0
          If ErrNum = 0 Then
            ' Ignore file and folders which give errors
            If (FileAttr And vbDirectory) = 0 Then
              ' File
              'Debug.Assert False
               Select Case Right$(FileName, 4)
                 Case ".pst", ".ost"
                 Cells(RowCrnt, "B").Value = FileName
                 With Cells(RowCrnt, "C")
                   .Value = FileLen(FldrName & "\" & FileName)
                   .NumberFormat = "#,##0"
                 End With
                 With Cells(RowCrnt, "D")
                   .Value = FileDateTime(FldrName & "\" & FileName)
                   .NumberFormat = "dmmmyy"
                 End With
                 Cells(RowCrnt, "E").Value = FldrName
                 RowCrnt = RowCrnt + 1
               End Select
            Else
              ' Directory
              ToSearch.Add FldrName & "\" & FileName
            End If  ' File or Directory
          Else
            'Debug.Print "FileAttr error: " & FldrName & "\" & FileName
          End If  ' FileAttr does not give an error
        End If ' Pointer or (File or Directory)
        FileName = Dir$
      Loop  ' For each pointer, file and sub-directory in folder
    End If  ' Dir$ gives error

    Range("A1") = ToSearch.Count
    Range("A2") = Range("A2") + 1
    DoEvents

  Loop  'until ToSearch empty

  Columns.AutoFit

End Sub
0
Tony Dallimore 4 अप्रैल 2020, 16:38