मेरे पास एक बैच स्क्रिप्ट है जो सभी फाइलों को एक फ़ोल्डर पर दूसरे में ले जाती है, लेकिन मैं यहां एक चर सम्मिलित करना चाहता हूं, जैसे: यदि उस फ़ोल्डर की किसी भी फाइल में नाम या नाम का हिस्सा है, उदाहरण के लिए, "घर", स्थानांतरित करें उस फ़ाइल को "घरों" फ़ोल्डर में, और यदि "कुत्ता" है, तो "कुत्ते" फ़ोल्डर में ले जाएं। याद रखें, नाम का हिस्सा है, फ़ाइल का विस्तार नहीं।

मेरी स्क्रिप्ट का एक हिस्सा जो काम करता है वह है, लेकिन यह सभी फाइलों को स्थानांतरित करता है:

@echo off

move D:\"FUNDACIÓN CB"\"Carteles temp"\*.* D:\"FUNDACIÓN CB"\"Carteles antiguos"
1
Pedro Corchero Murga 5 जिंदा 2021, 11:45

1 उत्तर

सबसे बढ़िया उत्तर
@ECHO Off
SETLOCAL ENABLEDELAYEDEXPANSION
rem The following settings for the source directory, destination directory, target directory,
rem batch directory, filenames, output filename and temporary filename [if shown] are names
rem that I use for testing and deliberately include names which include spaces to make sure
rem that the process works using such names. These will need to be changed to suit your situation.
SET "sourcedir=u:\your files"
SET "destdir=u:\your results"

FOR /f "delims=" %%s IN (
 'dir /b /ad "%destdir%\*" '
 ) DO (
 FOR /f "delims=" %%a IN (
  'dir /b /a-d "%sourcedir%\*%%s*" 2^>nul'
  ) DO (
  SET "match=%%~na"
  IF "%%~na" neq "!match:%%s=!" MOVE "%sourcedir%\%%a" "%destdir%\%%s\" >nul
 )
)
MOVE "%sourcedir%\*" "%destdir%\"

सबसे पहले, गंतव्य निर्देशिका में मौजूद निर्देशिका नाम एकत्र करें और प्रत्येक को बदले में %%s को असाइन करें।

प्रत्येक के साथ, उन फ़ाइल नामों की तलाश करें जिनमें निर्देशिका नाम %%s है और फिर जांच करें कि फ़ाइल के name भाग में delayedexpansion का उपयोग करके और फ़ाइल नाम से निर्देशिका नाम को हटाकर निर्देशिका नाम शामिल है। यदि फ़ाइल नाम में वास्तव में निर्देशिका नाम शामिल है, तो फ़ाइल %%a को स्रोत निर्देशिका से मिली उपनिर्देशिका में ले जाएं।

आखिरकार। जब प्रत्येक उपनिर्देशिका नाम संसाधित हो गया हो, तो शेष फ़ाइलों को स्रोत से गंतव्य निर्देशिका में ले जाएँ।

1
Magoo 5 जिंदा 2021, 14:22