वर्कशीट को वर्तमान फ़ोल्डर में सहेजने के लिए VBA

SaveAs को सहेजने के लिए पूर्ण पथ की तलाश है, इसलिए सक्रिय कार्यपुस्तिका में निर्देशिका प्राप्त करने के लिए ActiveWorkbook.Path का उपयोग करें, फिर इसमें \ और Fname संलग्न करें (मान लें कि आप विंडोज़ में काम कर रहे हैं)।

Sub SavePlan()

  Dim Fname As String
  Fname = Sheets("Main").Range("C6").Value
  
  Sheets("Main").Copy
  With ActiveWorkbook
    .SaveAs Filename := ActiveWorkbook.Path & "\" & Fname
    .Close
    End With

End Sub

Sub SavePlan()

    Dim Fname As String
    With Sheets("Main")
        Fname = .Parent.Path & "\" & .Range("C6").Value
        .Copy
    End With
    
    With ActiveWorkbook
        .SaveAs Filename:=Fname
        .Close
    End With

End Sub

एक नई कार्यपुस्तिका में बैकअप वर्कशीट

Option Explicit

Sub SavePlan()
    
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    Dim sws As Worksheet: Set sws = wb.Worksheets("Main")
    
    Dim FolderPath As String: FolderPath = wb.Path
    Dim dFileName As String: dFileName = sws.Range("C6").Value
    Dim dFilePath As String
    dFilePath = FolderPath & Application.PathSeparator & dFileName
    
    sws.Copy ' copy to a new (destination) workbook
    
    Dim dwb As Workbook: Set dwb = Workbooks(Workbooks.Count)
    
    Application.DisplayAlerts = False ' overwrite without confirmation
    dwb.SaveAs Filename:=dFilePath
    Application.DisplayAlerts = True
    
    dwb.Close SaveChanges:=False

    MsgBox "Worksheet backed up.", vbInformation

End Sub